// for rendering, use commands:
// povray -Q9 +A +UL +UV +W3200 +H2400 -Idomino.pov
// pngtopnm domino.png | pnmtojpeg >domino.jpg

#include "colors.inc"
#include "stones.inc"
#include "woods.inc"

#declare camX = <-30,0,0>;      // observer's left-right offset
camera { location camX+<0,-50,-18> look_at camX+<0,0,-10> }
light_source { camX+<150,-100,-350> color White }
light_source { camX+<1500,-1500,-50000> color rgb<0.2,0.2,0.2> }

// sky
background { color rgb <.7, .7, 1> }

// ground
plane { <0,0,1>, 10.0 texture { T_Stone19 scale 20 } } 

// a single domino stone
#declare piece = box { <0,0,2>, <4,0.5,10> }

// "infinite" chain, reachable by induction
#declare radB = <3600,0,0>;     // radius of big circle segment
#declare i=0;
#while(i<1100)
        object { piece
                translate radB 
                rotate <0,0,i*0.07> 
                translate -radB 
                texture { T_Wood10 scale 5 } 
        }
        #declare i=i+1;
#end

// junk terms, not reachable by induction
#declare radW = <40,0,0>;       // radius of small circle
#declare i=0;
#while(i<90)
        object { piece 
                translate radW 
                rotate <0,0,i*4> 
                translate -radW
                translate <-15,70,0>
                texture { T_Wood2 scale 5 } 
        }
        #declare i=i+1;
#end